Add offline mode: play from a music folder instead of the server

Settings has a Music folder row. A folder with subfolders is played as
soundtracks: Next picks a random subfolder and a random song in it, the
subfolder is the answer's soundtrack and the file name without its type the
song. The inspiration list and Search show the subfolders.

A folder with songs and no subfolders is a prepared quiz, played once in order
(natural sort) or at random, showing only the song title. It has no winning
score: after the last song Next becomes Show winner, and the players with the
most points win, ties included.

While a folder is used nothing but the characters is asked from the server:
Sync, QR, Statistics, the update check and play counting are off. Characters
fall back to the cached pictures when the server can't be reached. mp3, ogg and
wav play; other files and broken ones are skipped.

The old local playback code, the hidden Open button and the hidden Local toggle
are removed. Next now waits for the song to start before preparing the next one.

popups/winner_popup.gd

@@ -22,43 +22,95 @@ func _ready() -> void:
 
 
 func show_winner(winner: PlayerObject) -> void:
+	var winners: Array[PlayerObject] = [winner]
+	show_winners(winners)
+
+
+## Shows [param winners], who share the top score, with everyone else's placing below.
+## Tied players get the same placing. With no players, it says the quiz is over.
+func show_winners(winners: Array[PlayerObject]) -> void:
 	visible = true
-	winner_label.text = winner.player_name + " won with " + str(winner.player_score) + \
-	" points!!"
-	winner_picture.texture = winner.character
-	# The "no character" placeholder is pixel art, which blurs when scaled up smoothly
-	if winner.character.resource_path == PlayerObject.NO_CHARACTER_PATH:
-		winner_picture.texture_filter = CanvasItem.TEXTURE_FILTER_NEAREST
-	else:
-		winner_picture.texture_filter = CanvasItem.TEXTURE_FILTER_LINEAR
+	winner_label.text = winners_text(winners)
+	_show_pictures(winners)
 
-	# Clear previous player list entries
 	for child: Node in players_list.get_children():
 		child.queue_free()
-
-	# Sort players by score (descending) and add to list
-	var sorted_players: Array = Settings.player_array.duplicate()
+	var sorted_players: Array[PlayerObject] = Settings.player_array.duplicate()
 	sorted_players.sort_custom(
 		func(a: PlayerObject, b: PlayerObject) -> bool:
 			return a.player_score > b.player_score
 	)
-
-	var placing: int = 2
 	for player: PlayerObject in sorted_players:
-		if player == winner:
-			continue  # Skip the winner, already shown above
+		if player in winners:
+			continue
 		var label: Label = Label.new()
-		label.text = str(placing) + ". " + player.player_name + " - " + \
-			str(player.player_score) + " points"
+		label.text = "%d. %s - %s" % [placing(player), player.player_name,
+				points_text(player.player_score)]
 		players_list.add_child(label)
-		placing += 1
 
 	show_history(ScoreHistory.from_playlist(Settings.player_array))
 
 
+## The headline for [param winners], e.g. "Crono won with 5 points!!" or "Crono and
+## Marle won with 5 points!!".
+static func winners_text(winners: Array[PlayerObject]) -> String:
+	if winners.is_empty():
+		return "The quiz is over!"
+	var names: PackedStringArray = []
+	for winner: PlayerObject in winners:
+		names.append(winner.player_name)
+	var joined: String = names[-1]
+	if names.size() > 1:
+		joined = ", ".join(names.slice(0, -1)) + " and " + names[-1]
+	return "%s won with %s!!" % [joined, points_text(winners[0].player_score)]
+
+
+## [param points] in words, e.g. "1 point" or "5 points".
+static func points_text(points: int) -> String:
+	return "%d point%s" % [points, "" if points == 1 else "s"]
+
+
+## Where [param player] placed: 1 plus how many players have more points, so tied
+## players share a placing.
+static func placing(player: PlayerObject) -> int:
+	var place: int = 1
+	for other: PlayerObject in Settings.player_array:
+		if other.player_score > player.player_score:
+			place += 1
+	return place
+
+
+# One picture per winner, next to each other
+func _show_pictures(winners: Array[PlayerObject]) -> void:
+	var header: Node = winner_picture.get_parent()
+	for extra: Node in header.get_children():
+		if extra != winner_picture && extra is TextureRect:
+			header.remove_child(extra)
+			extra.queue_free()
+	winner_picture.visible = !winners.is_empty()
+	for index: int in winners.size():
+		var picture: TextureRect = winner_picture
+		if index > 0:
+			picture = winner_picture.duplicate()
+			header.add_child(picture)
+			header.move_child(picture, winner_picture.get_index() + index)
+		_show_character(picture, winners[index])
+
+
+func _show_character(picture: TextureRect, player: PlayerObject) -> void:
+	picture.texture = player.character
+	# The "no character" placeholder is pixel art, which blurs when scaled up smoothly
+	if player.character.resource_path == PlayerObject.NO_CHARACTER_PATH:
+		picture.texture_filter = CanvasItem.TEXTURE_FILTER_NEAREST
+	else:
+		picture.texture_filter = CanvasItem.TEXTURE_FILTER_LINEAR
+
+
 ## Shows how the game went: the score graph, its legend and the summary boxes.
 func show_history(history: ScoreHistory) -> void:
-	score_graph.show_history(history, Settings.winning_score)
+	# A prepared quiz has no winning score to draw
+	var winning_score: int = 0 if Settings.is_prepared_quiz() else Settings.winning_score
+	score_graph.show_history(history, winning_score)
 	streak_label.text = history.longest_streak_text()
 	standstill_label.text = history.longest_standstill_text()
 	shared_label.text = history.most_shared_text()