Sort the scripts and scenes into folders

main/ holds the main window and top bar, quiz/ the quiz and its parts,
player/ the music player, popups/ every popup and what they share, data/ the
songs, players, playlist and settings, server/ the MusicServer client,
common/ the list row and GameLog, and themes/ the themes and style boxes.

data/player_object.gd

@@ -0,0 +1,70 @@
+class_name PlayerObject
+extends RefCounted
+## A player in the quiz: name, score and character. The players are kept in
+## [code]Settings.player_array[/code].
+
+signal first_point_triggered
+signal match_point_triggered
+signal winner_triggered
+signal point_given_sound
+signal player_point_given
+signal player_point_taken
+
+## Picture shown until the player picks a character.
+const NO_CHARACTER_PATH: String = "res://noCharacter.png"
+
+@export var player_name: String
+@export var player_score: int
+
+## Unique id that never changes, unlike the player's position in Settings.player_array.
+var id: String = _generate_uuid()
+
+var is_first_point: bool = true
+var character: Texture = load(NO_CHARACTER_PATH)
+
+
+func _init(new_name: String) -> void:
+	player_name = new_name
+	player_score = 0
+
+
+## Returns a random version 4 UUID, e.g. "3f2b8c1e-9a4d-4e7f-b2c6-5d8e1f0a7b93".
+static func _generate_uuid() -> String:
+	var bytes: PackedByteArray = Crypto.new().generate_random_bytes(16)
+	bytes[6] = (bytes[6] & 0x0f) | 0x40
+	bytes[8] = (bytes[8] & 0x3f) | 0x80
+	var hex: String = bytes.hex_encode()
+	return "%s-%s-%s-%s-%s" % [hex.substr(0, 8), hex.substr(8, 4), hex.substr(12, 4),
+			hex.substr(16, 4), hex.substr(20, 12)]
+
+
+func add_point() -> void:
+	if player_score < Settings.winning_score:
+		player_score += 1
+		player_point_given.emit()
+		var first_point: bool = player_score == 1 && is_first_point
+		if player_score == 1:
+			is_first_point = false
+		# With a low winning score the first point can also be match point or the win,
+		# so the more important event is checked first
+		if player_score == Settings.winning_score:
+			winner_triggered.emit()
+		elif player_score == Settings.winning_score - 1:
+			match_point_triggered.emit()
+		elif first_point:
+			first_point_triggered.emit()
+		else:
+			point_given_sound.emit()
+
+
+func minus_point() -> void:
+	if player_score > 0:
+		player_score -= 1
+		player_point_taken.emit()
+		if player_score == 0:
+			is_first_point = true
+
+
+func reset_points() -> void:
+	player_score = 0
+	is_first_point = true

data/player_object.gd.uid

@@ -0,0 +1 @@
+uid://83f1fdubqdxy

data/playlist.gd

@@ -0,0 +1,122 @@
+extends Node
+## The songs of the current quiz, in the order they were added, and which of them are
+## played, answered and playing.
+##
+## Registered as the [code]Playlist[/code] autoload.
+
+var song_object_array: Array[SongObject] = []
+var latest_played_song: int = 0
+var currently_playing_song: int = -1
+var first_song_downloaded: bool = false
+var first_song_played: bool = false
+var number_of_tracks_to_preload: int = 1
+var is_song_downloading: bool = false
+
+
+func get_next_song() -> SongObject:
+	return song_object_array[latest_played_song]
+
+
+func set_latest_played_song() -> void:
+	latest_played_song += 1
+	if latest_played_song > song_object_array.size() - 1:
+		latest_played_song = song_object_array.size() - 1
+
+
+func update_last_played_song() -> void:
+	latest_played_song = song_object_array.size()
+
+
+func get_preloaded_songs() -> int:
+	var number_of_tracks_preloaded: int = 0
+	for song: SongObject in song_object_array:
+		if !song.has_played:
+			number_of_tracks_preloaded += 1
+	return number_of_tracks_preloaded
+
+
+func should_preload_more_songs() -> bool:
+	return number_of_tracks_to_preload > get_preloaded_songs()
+
+
+func song_is_answered(song_no: int = currently_playing_song) -> void:
+	# Nothing is playing yet (-1); a negative index would answer the last, unplayed song
+	if song_no < 0 || song_no >= song_object_array.size():
+		return
+	GameLog.debug("show_answer_pressed song_object: ", song_object_array[song_no]._to_string())
+	song_object_array[song_no].is_answered = true
+	if Settings.add_to_stats:
+		GameLog.debug("add to stats: ", song_no)
+		MusicServerClient.mark_song_played(song_no)
+
+
+func add_to_playlist(new_song_object: SongObject) -> void:
+	song_object_array.append(new_song_object)
+
+
+func get_playlist() -> Array[SongObject]:
+	if Settings.is_debug:
+		return song_object_array
+	else:
+		var temp_list: Array[SongObject] = []
+		for s: SongObject in song_object_array:
+			if s.has_played:
+				temp_list.append(s)
+		return temp_list
+
+
+func reset_playlist() -> void:
+	currently_playing_song = -1
+	latest_played_song = 0
+	clear_song_list()
+
+
+func clear_song_list() -> void:
+	song_object_array.clear()
+
+
+func unset_is_playing() -> void:
+	for song_object: SongObject in song_object_array:
+		song_object.is_playing = false
+
+
+func set_currently_playing_song(value: int) -> void:
+	currently_playing_song = value
+
+
+func get_current_soundtrack_title() -> String:
+	return song_object_array[currently_playing_song].get_soundtrack_title()
+
+
+func get_current_song_title() -> String:
+	return song_object_array[currently_playing_song].get_song_title()
+
+
+func add_point(player_id: String) -> void:
+	song_object_array[currently_playing_song].add_point(player_id)
+
+
+func remove_point(player_id: String) -> void:
+	song_object_array[currently_playing_song].remove_point(player_id)
+
+
+## Removes a player's points from every song.
+func remove_player_from_list(player_id: String) -> void:
+	for song_object: SongObject in song_object_array:
+		song_object.remove_point(player_id)
+
+
+func get_song(song_no: int) -> AudioStream:
+	return song_object_array[song_no].song
+
+
+func add_song_to_song_object(song_no: int, sound: AudioStream) -> void:
+	song_object_array[song_no].song = sound
+
+
+func song_has_played(song_no: int = latest_played_song) -> void:
+	song_object_array[song_no].has_played = true
+
+
+func song_is_playing(song_no: int = latest_played_song) -> void:
+	song_object_array[song_no].is_playing = true

data/playlist.gd.uid

@@ -0,0 +1 @@
+uid://bgei7qocdnolw

data/settings.gd

@@ -0,0 +1,38 @@
+extends Node
+## The game settings and the players, shared by the whole game.
+##
+## Registered as the [code]Settings[/code] autoload.
+
+const MAX_NUMBER_OF_PLAYERS: int = 7
+
+var default_path: String = "https://music.sanplex.xyz"
+var selected_server: int = 0
+var is_local: bool = false
+var is_debug: bool = false
+var stop_after_current: bool = true
+var auto_repeat_song: bool = true
+var hide_next_track: bool = true
+var add_to_stats: bool = true
+var use_low_played_mode: bool = false
+var winning_score: int = 20
+var fullscreen: bool = false
+var play_local: bool = false
+var inspiration_list_speed: int = 1
+var hide_for_seconds: float = 5.0
+var hide_beginning: bool = false
+var hide_length: bool = false
+var hide_ticks: bool = false
+var player_array: Array[PlayerObject]
+var edit_players: bool = false
+var currently_syncing: bool = false
+var character_select_open: bool = false
+
+## The game version, set in Project Settings > Application > Config > Version.
+## Releases are made from it, see RELEASING.md.
+var version: String = ProjectSettings.get_setting("application/config/version", "")
+
+
+func delete_children(node: Node) -> void:
+	for n: Node in node.get_children():
+		node.remove_child(n)
+		n.queue_free()

data/settings.gd.uid

@@ -0,0 +1 @@
+uid://dex06sca65j4t

data/song_object.gd

@@ -0,0 +1,59 @@
+extends RefCounted
+
+class_name SongObject
+
+var song_number: int
+var song_title: String
+var soundtrack_title: String
+
+## Ids of the players who got a point for this song.
+var players_given_point: Array[String] = []
+
+var is_answered: bool = false
+var has_played: bool = false
+var is_playing: bool = false
+var song: AudioStream
+
+
+func get_soundtrack_title() -> String:
+	if is_answered:
+		return soundtrack_title
+	else:
+		return "????????"
+
+
+func get_song_title() -> String:
+	if is_answered:
+		return song_title
+	else:
+		return "??????"
+
+
+func get_song_info() -> String:
+	if Settings.is_debug:
+		var format_string: String = "%d. %s - %s | played: %s | answered: %s"
+		return format_string % [(song_number + 1), soundtrack_title, song_title, has_played,
+				is_answered]
+	elif is_answered:
+		var format_string: String = "%d. %s - %s"
+		return format_string % [(song_number + 1), soundtrack_title, song_title]
+	else:
+		return "??? - ???"
+
+
+func add_point(player_id: String) -> void:
+	GameLog.debug("add_point")
+	if !players_given_point.has(player_id):
+		players_given_point.append(player_id)
+
+
+func remove_point(player_id: String) -> void:
+	GameLog.debug("remove_point")
+	players_given_point.erase(player_id)
+
+
+func _to_string() -> String:
+	var format_string: String = "song_number: %d | soundtrack_title: %s | song_title: %s" \
+			+ " | is_answered: %s | has_played: %s | is_playing: %s"
+	return format_string % [song_number, soundtrack_title, song_title, is_answered, has_played,
+			is_playing]

data/song_object.gd.uid

@@ -0,0 +1 @@
+uid://d1o4ys4qqxfcp